home *** CD-ROM | disk | FTP | other *** search
/ Softdisk Supreme / Softdisk Supreme.iso / pc / DSK Files / 0-49 / SD004b.dsk / DICTIONARY.GAME.bas < prev    next >
BASIC Source File  |  2003-06-12  |  7KB  |  163 lines
  1. 5  REM    *** DICTIONARY.GAME ***
  2. 100  REM                           -----------------------     DOCUMENTATION.MODULE        -----------------------
  3. 110  REM                          CR = CORNER OF PAGE
  4. 120  REM                          DH = DICTIONARY HOLDER
  5. 130  REM                          I  = GENERAL INDEX
  6. 140  REM                          LG = LENGTH
  7. 150  REM                          LP = LAST PAGE
  8. 160  REM                          NP = NUMBER OF PLAYERS
  9. 170  REM                          PG = PAGE NUMBER
  10. 180  REM                          PL = PLAYER NUMBER
  11. 190  REM                          PL$(20) = ARRAY FOR                   PLAYER NAMES
  12. 200  REM                          R$ = GENERAL RESPONSE                    VARIABLE
  13. 210  REM                          SC(20) = ARRAY FOR                   PLAYER'S SCORES
  14. 220  REM                          WD = WORD NUMBER
  15. 300  REM                          ------------------------    HOUSEKEEPING.MODULE         ------------------------
  16. 310  DIM PL$(20)
  17. 320  DIM SC(20)
  18. 500  REM                          ------------------------    EXECUTIVE.MODULE            ------------------------
  19. 520  GOSUB 1000
  20. 530  GOSUB 2000
  21. 540  GOSUB 3000
  22. 550  GOTO 540
  23. 999  END 
  24. 1000  REM                         ------------------------    GAME.INSTRUCTIONS           ------------------------
  25. 1020  TEXT : HOME 
  26. 1030  VTAB (8): HTAB (14)
  27. 1040  PRINT "DICTIONARY GAME"
  28. 1050  VTAB (12)
  29. 1060  INPUT "DO YOU NEED INSTRUCTIONS? (Y OR N) ";R$
  30. 1070  IF R$ = "N" GOTO 1990
  31. 1080  HOME : VTAB (6)
  32. 1090  PRINT "DICTIONARY.GAME REQUIRES AN APPLE,"
  33. 1100  PRINT "A DICTIONARY, A RULER AND AT LEAST TWO"
  34. 1110  PRINT "PLAYERS.
  35. 1120  PRINT : PRINT "THE OBJECT OF THE GAME IS TO SHARPEN"
  36. 1130  PRINT "VOCABULARY AND STIMULATE CONVERSATION."
  37. 1140  PRINT : PRINT "THE PRIMARY PART THE APPLE PLAYS IS TO"
  38. 1150  PRINT "RANDOMLY SELECT A WORD FROM THE"
  39. 1160  PRINT "DICTIONARY.  THE APPLE ALSO KEEPS"
  40. 1170  PRINT "SCORE."
  41. 1180  GOSUB 8000
  42. 1190  HOME : VTAB (4)
  43. 1200  PRINT "HERE'S HOW PLAY GOES ----"
  44. 1210  PRINT : PRINT "FIRST THE APPLE ASKS FOR THE"
  45. 1220  PRINT "NAMES OF ALL THE PLAYERS."
  46. 1230  PRINT : PRINT "NEXT THE APPLE SELECTS A PLAYER"
  47. 1240  PRINT "TO BE THE DICTIONARY HOLDER."
  48. 1250  PRINT "(THIS DUTY WILL BE ROTATED)": PRINT 
  49. 1260  PRINT "THE APPLE PROCEEDS TO DIRECT THE"
  50. 1270  PRINT "DICTIONARY HOLDER TO A WORD IN THE"
  51. 1280  PRINT "FOLLOWING MANNER:": PRINT 
  52. 1290  PRINT "  1. A PAGE NUMBER IS SPECIFIED"
  53. 1300  PRINT "  2. A PAGE CORNER IS SPECIFIED"
  54. 1310  PRINT "  3. A LENGTH IS SPECIFIED"
  55. 1320  GOSUB 8000
  56. 1330  HOME : VTAB (4)
  57. 1340  PRINT "FOR EXAMPLE THE APPLE MIGHT SPECIFY:": PRINT 
  58. 1350  PRINT "PAGE 116 - LOWER LEFT - 3 INCHES": PRINT 
  59. 1360  PRINT "THE DICTIONARY HOLDER WOULD TURN TO"
  60. 1370  PRINT "PAGE 116 AND STARTING AT THE LOWER "
  61. 1380  PRINT "LEFT HAND CORNER OF THE PAGE; MEASURE"
  62. 1390  PRINT "UP 3 INCHES."
  63. 1400  PRINT : PRINT "THE WORD NEAREST TO THE END OF THE"
  64. 1410  PRINT "RULER WOULD BE THE SELECTED WORD."
  65. 1420  PRINT : PRINT "ONCE THE WORD HAS BEEN SELECTED THE"
  66. 1430  PRINT "DICTIONARY HOLDER SPELLS AND"
  67. 1440  PRINT "PRONOUNCES IT."
  68. 1450  GOSUB 8000
  69. 1460  HOME : VTAB (4)
  70. 1470  PRINT "THE PLAYERS THEN ATTEMPT TO DEFINE THE"
  71. 1480  PRINT "WORD.  THE DICTIONARY HOLDER IS THE"
  72. 1490  PRINT "JUDGE OF WETHER A DEFINITION IS CORRECT"
  73. 1500  PRINT "OR NOT."
  74. 1510  PRINT : PRINT "DEFINITIONS DO NOT HAVE TO BE PRECISE"
  75. 1520  PRINT "BUT THEY SHOULD CONVEY THAT YOU KNOW"
  76. 1530  PRINT "WHAT THE WORD MEANS."
  77. 1540  PRINT : PRINT "YOU CAN ADOPT YOUR OWN HOUSE RULES BUT"
  78. 1550  PRINT "I GIVE AS MUCH CREDIT TO A PLAYER WHO"
  79. 1560  PRINT "AGREES WITH A CORRECT DEFINITION AS TO"
  80. 1570  PRINT "THE PLAYER WHO STATED THE DEFINITION."
  81. 1580  PRINT : PRINT "REMEMBER, THE PURPOSE OF THE GAME IS TO"
  82. 1590  PRINT "STIMULATE CONVERSATION."
  83. 1600  GOSUB 8000
  84. 1610  HOME : VTAB (4)
  85. 1620  PRINT "YOU MIGHT WANT TO DIVIDE UP INTO TEAMS"
  86. 1630  PRINT "AND WRITE YOUR DEFINITIONS DOWN PRIOR"
  87. 1640  PRINT "TO REVEALING THEM."
  88. 1650  PRINT : PRINT "EACH TIME THE APPLE IS INSTRUCTED TO"
  89. 1660  PRINT "SELECT A NEW WORD, A NEW DICTIONARY"
  90. 1670  PRINT "HOLDER IS SELECTED ALSO."
  91. 1680  PRINT : PRINT "YOU MAY SET YOUR OWN END OF GAME POLICY"
  92. 1690  PRINT "BASED ON TIME OR NUMBER OF WORDS."
  93. 1700  PRINT : PRINT : HTAB (12)
  94. 1710  PRINT "GOOD LUCK!"
  95. 1720  GOSUB 8000
  96. 1990  RETURN 
  97. 2000  REM                         ------------------------    GET.PLAYER'S.NAMES          ------------------------
  98. 2010  HOME : VTAB (4)
  99. 2020  PRINT "   TELL ME THE NAMES OF ALL PLAYERS"
  100. 2030  VTAB (8): HTAB (2)
  101. 2040  PRINT "FIRST NAME AND INITIAL OF LAST NAME"
  102. 2050  PRINT "              WILL DO"
  103. 2055  VTAB 20: HTAB 3
  104. 2060  FLASH : PRINT "*";: NORMAL : PRINT " RETURN WITH NO INPUT WHEN THRU ";: FLASH : PRINT "*": NORMAL 
  105. 2070 PL = PL +1
  106. 2080  VTAB (14): CALL  -868
  107. 2090  PRINT "PLAYER NO. ";PL;: INPUT " ";PL$(PL)
  108. 2100  IF PL$(PL) < >"" GOTO 2070
  109. 2105 NP = PL -1
  110. 2110  HOME : VTAB 12
  111. 2120  PRINT "IN YOUR DICTIONARY,"
  112. 2130  PRINT : INPUT "ON WHAT PAGE IS THE WORD ZYME? ";LP
  113. 3000  REM                         ------------------------    PLAY.A.TURN                 ------------------------
  114. 3010  GOSUB 4000
  115. 3020  GOSUB 5000
  116. 3030  GOSUB 6000
  117. 3040  RETURN 
  118. 4000  REM                         ------------------------    SELECT.DICTIONARY.HOLDER    ------------------------
  119. 4010  HOME : VTAB 4
  120. 4020  HTAB 8
  121. 4030  PRINT "THE DICTIONARY HOLDER IS"
  122. 4040 DH = DH +1: IF DH >NP  THEN DH = 1
  123. 4050  PRINT : HTAB 15
  124. 4060  PRINT PL$(DH)
  125. 4070  RETURN 
  126. 5000  REM                         ------------------------    SELECT.A.WORD               ------------------------
  127. 5010 PG =  INT( RND(1) *(LP +1))
  128. 5020 CR =  INT( RND(1) *4) +1
  129. 5030 LG =  INT( RND(1) *80)/10
  130. 5040  VTAB (12): HTAB (12)
  131. 5050  PRINT "PAGE ";PG
  132. 5060  VTAB (14): HTAB (12)
  133. 5070  IF CR = 1  THEN  PRINT "UPPER LEFT"
  134. 5080  IF CR = 2  THEN  PRINT "UPPER RIGHT"
  135. 5090  IF CR = 3  THEN  PRINT "LOWER LEFT"
  136. 5100  IF CR = 4  THEN  PRINT "LOWER RIGHT"
  137. 5110  VTAB 16: HTAB (12)
  138. 5120  PRINT LG;" INCHES"
  139. 5130  VTAB 22
  140. 5140  INPUT "HIT RETURN WHEN READY TO POST SCORES ";R$
  141. 5150  RETURN 
  142. 6000  REM                         ------------------------    GET.SCORES                  ------------------------
  143. 6010  HOME : PRINT "ENTER AN  X  FOR CREDIT,"
  144. 6020  PRINT "HIT SPACE BAR FOR NO CREDIT"
  145. 6030  PRINT 
  146. 6035 WD = WD +1: VTAB 24: HTAB 12: PRINT "WORD NUMBER ";WD;: VTAB 4
  147. 6040  FOR I = 1 TO PL -1
  148. 6050  HTAB 3: PRINT "SCORE = ";SC(I);: HTAB 15: PRINT PL$(I)
  149. 6060  NEXT I
  150. 6070  FOR I = 1 TO PL -1
  151. 6080  VTAB 3 +I
  152. 6090  GET R$
  153. 6100  IF R$ = "X"  THEN SC(I) = SC(I) +1
  154. 6110  PRINT R$;: HTAB 3: PRINT "SCORE = ";SC(I)
  155. 6120  NEXT I
  156. 6130  VTAB 24
  157. 6135  CALL  -868
  158. 6140  INPUT "HIT RETURN FOR A NEW WORD ";R$
  159. 6150  RETURN 
  160. 8000  REM                         ------------------------    ASK.FOR.RETURN              ------------------------
  161. 8010  VTAB (24): HTAB (12)
  162. 8020  INPUT "** HIT RETURN ** ";R$
  163. 8030  RETURN